#include "config.h"

#if PCB_REVISION >= 12
I2C_eeprom ee(0x50, EEPROM_SIZE_BYTES);
#endif

LubeConfig_t LubeConfig;
persistenceData_t PersistenceData;
uint16_t eePersistenceMarker = 0;
uint16_t eeVersion = 0; // inc
boolean eeAvailable = false;

const uint16_t startofLubeConfig = 16;
const uint16_t startofPersistence = 16 + sizeof(LubeConfig) + (sizeof(LubeConfig) % 16);

#if PCB_REVISION >= 12
void InitEEPROM()
{
  ee.begin();
  if (!ee.isConnected())
    Serial.println(PSTR("ERROR: Can't find eeprom..."));
}
#endif

void EEPROM_Process()
{

  switch (globals.requestEEAction)
  {
  case EE_CFG_SAVE:
    StoreConfig_EEPROM();
    Serial.println("EE_CFG_SAVE");
    globals.requestEEAction = EE_IDLE;
    break;
  case EE_CFG_LOAD:
    GetConfig_EEPROM();
    Serial.println("EE_CFG_LOAD");
    globals.requestEEAction = EE_IDLE;
    break;
  case EE_PDS_SAVE:
    StorePersistence_EEPROM();
    Serial.println("EE_PDS_SAVE");
    globals.requestEEAction = EE_IDLE;
    break;
  case EE_PDS_LOAD:
    GetPersistence_EEPROM();
    Serial.println("EE_PDS_LOAD");
    globals.requestEEAction = EE_IDLE;
    break;
  case EE_IDLE:
  default:
    globals.requestEEAction = EE_IDLE;
  }
}

void StoreConfig_EEPROM()
{
  LubeConfig.checksum = 0;
  LubeConfig.checksum = Checksum_EEPROM((uint8_t *)&LubeConfig, sizeof(LubeConfig));
#if PCB_REVISION >= 12
  if (!ee.isConnected())
    return;
  ee.updateBlock(startofLubeConfig, (uint8_t *)&LubeConfig, sizeof(LubeConfig));
#else
  EEPROM.begin(512);
  EEPROM.put(startofLubeConfig, LubeConfig);
  EEPROM.commit();
  EEPROM.end();
#endif
}

void GetConfig_EEPROM()
{
#if PCB_REVISION >= 12
  if (!ee.isConnected())
    return;
  ee.readBlock(startofLubeConfig, (uint8_t *)&LubeConfig, sizeof(LubeConfig));
#else
  EEPROM.begin(512);
  EEPROM.get(startofLubeConfig, LubeConfig);
  EEPROM.end();
#endif

  uint32_t checksum = LubeConfig.checksum;
  LubeConfig.checksum = 0;

  if (Checksum_EEPROM((uint8_t *)&LubeConfig, sizeof(LubeConfig)) != checksum)
  {
    Serial.printf(PSTR("CFG EEPROM Checksum BAD\n"));
    FormatConfig_EEPROM();
  }
  LubeConfig.checksum = checksum;
}

void StorePersistence_EEPROM()
{
  if (PersistenceData.writeCycleCounter >= 0xFFF0)
    MovePersistencePage_EEPROM(false);
  else
    PersistenceData.writeCycleCounter++;

  uint16_t PersistenceDataAddress = startofPersistence + eePersistenceMarker;
  PersistenceData.checksum = 0;
  PersistenceData.checksum = Checksum_EEPROM((uint8_t *)&PersistenceData, sizeof(PersistenceData));

#if PCB_REVISION >= 12
  if (!ee.isConnected())
    return;
  ee.updateBlock(PersistenceDataAddress, (uint8_t *)&PersistenceData, sizeof(PersistenceData));
#else
  EEPROM.put(PersistenceDataAddress, PersistenceData);
  EEPROM.commit();
  EEPROM.end();
#endif
}

void GetPersistence_EEPROM()
{
#if PCB_REVISION >= 12
  if (!ee.isConnected())
    return;
  eePersistenceMarker = (ee.readByte(0) << 8) | ee.readByte(1);
#else
  EEPROM.begin(512);
  EEPROM.get(0, eePersistenceMarker);
#endif

  uint16_t PersistenceDataAddress = startofPersistence + eePersistenceMarker;

#if PCB_REVISION >= 12
  ee.readBlock(PersistenceDataAddress, (uint8_t *)&PersistenceData, sizeof(PersistenceData));
#else
  EEPROM.get(PersistenceDataAddress, PersistenceData);
  EEPROM.end();
#endif

  uint32_t checksum = PersistenceData.checksum;
  PersistenceData.checksum = 0;

  if (Checksum_EEPROM((uint8_t *)&PersistenceData, sizeof(PersistenceData)) != checksum)
  {
    Serial.printf(PSTR("Persistance EEPROM Checksum BAD\n"));
    FormatPersistence_EEPROM();
  }
  PersistenceData.checksum = checksum;
}

void FormatConfig_EEPROM()
{
  LubeConfig_t defaults;
  LubeConfig = defaults;
  StoreConfig_EEPROM();
}

void FormatPersistence_EEPROM()
{
  persistenceData_t defaults;
  PersistenceData = defaults;
  eePersistenceMarker = 0;
  StorePersistence_EEPROM();
}

void MovePersistencePage_EEPROM(boolean reset)
{
  eePersistenceMarker = reset ? sizeof(PersistenceData) : eePersistenceMarker + sizeof(PersistenceData);
  PersistenceData.writeCycleCounter = 0;

#if PCB_REVISION >= 12
  if (!ee.isConnected())
    return;
  ee.updateByte(0, (uint8_t)(eePersistenceMarker >> 8));
  ee.updateByte(1, (uint8_t)(eePersistenceMarker & 0xFF));
#else
  EEPROM.begin(512);
  EEPROM.put(0, eePersistenceMarker);
#endif
}

uint32_t Checksum_EEPROM(uint8_t const *data, size_t len)
{
  if (data == NULL)
    return 0;
  uint32_t crc, mask;
  crc = 0xFFFFFFFF;

  while (len--)
  {
    crc ^= *data++;
    for (uint8_t k = 0; k < 8; k++)
    {
      mask = -(crc & 1);
      crc = (crc >> 1) ^ (0xEDB88320 & mask);
    }
  }
  return ~crc;
}

void dumpEEPROM(uint16_t memoryAddress, uint16_t length)
{
#define BLOCK_TO_LENGTH 16

  if (!ee.isConnected())
    return;

  char ascii_buf[BLOCK_TO_LENGTH + 1];
  sprintf(ascii_buf, "%*s", BLOCK_TO_LENGTH, "ASCII");
  Serial.print(PSTR("\nAddress "));
  for (int x = 0; x < BLOCK_TO_LENGTH; x++)
    Serial.printf("%3d", x);

  memoryAddress = memoryAddress / BLOCK_TO_LENGTH * BLOCK_TO_LENGTH;
  length = (length + BLOCK_TO_LENGTH - 1) / BLOCK_TO_LENGTH * BLOCK_TO_LENGTH;

  for (unsigned int i = 0; i < length; i++)
  {
    int blockpoint = memoryAddress % BLOCK_TO_LENGTH;
    if (blockpoint == 0)
    {
      ascii_buf[BLOCK_TO_LENGTH] = 0;
      Serial.printf("  %s", ascii_buf);
      Serial.printf("\n0x%05X:", memoryAddress);
    }
    ascii_buf[blockpoint] = ee.readByte(memoryAddress);
    Serial.printf(" %02X", ascii_buf[blockpoint]);
    if (ascii_buf[blockpoint] < 0x20 || ascii_buf[blockpoint] > 0x7E)
      ascii_buf[blockpoint] = '.';
    memoryAddress++;
  }
  Serial.println();
}